@echo off

REM Analisis de los parametros
REM --------------------------

if "%1." == "." goto error
if NOT "%2." == "." goto error

REM Creacion de los directorios si fuesen necesarios
REM ------------------------------------------------

c:
cd \
if exist c:\multib\nul goto c0
md multib

:c0
cd multib
if exist c:\multib\%1.ini\nul goto c1
echo.
echo Nuevo sistema operativo a guardar
choice /C:SN Esta seguro...
if errorlevel 2 goto fin

md %1.ini

REM Crear fichero testigo
REM ---------------------

:c1
echo . > %1
cd %1.ini

REM Copia del sistema. Parte principal
REM ----------------------------------

attrib c:\msdos.sys -s -h -r
copy c:\msdos.sys  >nul
attrib c:\msdos.sys +s +h +r

attrib c:\io.sys -s -h -r
copy c:\io.sys     >nul
attrib c:\io.sys +s +h +r

copy c:\config.sys   >nul
copy c:\command.com  >nul
copy c:\autoexec.bat >nul

REM Para posibles errores en OSR 2
REM ------------------------------

copy io.sys winboot.sys >nul

REM Copiar algun logo, si este existiese
REM ------------------------------------

if exist c:\logo.sys attrib c:\logo.sys -s -h -r
if exist c:\logo.sys copy c:\logo.sys  >nul
if exist c:\logo.sys attrib c:\logo.sys +s +h +r

REM Copiar compresores de disco si existen
REM --------------------------------------

if exist c:\dbls*.* attrib c:\dbls*.* -s -h -r
if exist c:\dbls*.* copy c:\dbls*.*    >nul
if exist c:\dbls*.* attrib c:\dbls*.* +s +h +r

if exist c:\drvs*.* attrib c:\drvs*.* -s -h -r
if exist c:\drvs*.* copy c:\drvs*.*    >nul
if exist c:\drvs*.* attrib c:\drvs*.* +s +h +r

echo.
echo Copia realizada.
echo Si ha recibido algun mensaje de aviso o error, la copia puede ser invalida.
echo.

goto fin

:error
echo Error en parametros
echo 
goto fin

:fin